Uptimecheck mit Terraform verwalten

Aktualisiert am 15. November 2026 3 Min. Lesezeit

In Professional und Business verwaltet der Uptimecheck-Provider für Terraform, uptimecheck-com/uptimecheck in der Terraform Registry, Monitore, Projekte, Alarmkanäle und Statusseiten als Code. Er arbeitet über die REST API mit einem API-Schlüssel.

API-Schlüssel erstellen

  1. Öffnen Sie Einstellungen in der Seitenleiste und wählen Sie den Tab API.
  2. Wählen Sie Neuer API-Schlüssel, benennen Sie ihn nach seinem Einsatzort, etwa „Terraform“, und wählen Sie Lesen & Schreiben. Der Provider legt Dinge an und ändert sie, ein Nur-Lese-Schlüssel reicht also nicht.
  3. Wählen Sie Schlüssel erstellen und kopieren Sie ihn. Er wird nur dieses eine Mal angezeigt.

Provider einbinden

Fügen Sie den Provider Ihrer Konfiguration hinzu:

terraform {
  required_providers {
    uptimecheck = {
      source = "uptimecheck-com/uptimecheck"
    }
  }
}

provider "uptimecheck" {}

Führen Sie terraform init aus; der Befehl lädt den Provider aus der Terraform Registry. Hinterlegen Sie den Schlüssel dann in der Umgebungsvariable UPTIMECHECK_API_KEY, etwa mit export UPTIMECHECK_API_KEY=uc_your_api_key, oder als Secret in Ihrem CI-System. Der Provider kennt auch ein Argument api_key, mit der Umgebungsvariable bleibt der Schlüssel aber aus Ihren Dateien heraus.

Monitor hinzufügen

resource "uptimecheck_monitor" "checkout" {
  type             = "http"
  name             = "Checkout"
  target           = "https://shop.example.com/checkout"
  interval_seconds = 60
  config = jsonencode({
    expectedStatus = "200-299"
    keyword        = { value = "Add to cart", mode = "contains" }
    slowMs         = 1500
  })
}
  • type ist einer von http, tcp, ping, dns, domain, heartbeat, server, vendor, crawl und flow. Eine Änderung ersetzt den Monitor.
  • config enthält die Einstellungen des Typs als JSON, mit denselben Schlüsseln wie in der API-Referenz. Verwaltet werden nur die Schlüssel, die Sie schreiben, die Standardwerte der App für den Rest erscheinen also nicht als Änderungen.
  • interval_seconds legt fest, wie oft geprüft wird: 60 bis 3600 Sekunden (30 in Tarifen, die das erlauben), ohne Angabe 300.
  • channel_ids wählt die Alarmkanäle, project_id das Projekt, und paused = true pausiert den Monitor.

Führen Sie terraform plan aus, um zu sehen, was sich ändert, dann terraform apply. Der Monitor erscheint sofort in der App.

Ein Cron-Job und seine Ping-URL

resource "uptimecheck_monitor" "backup" {
  type = "heartbeat"
  name = "Nightly backup"
  config = jsonencode({
    schedule      = { cron = "0 3 * * *", timeZone = "Europe/Stockholm" }
    graceSeconds  = 900
    maxRunSeconds = 3600
  })
}

output "backup_ping_url" {
  value     = uptimecheck_monitor.backup.heartbeat_url
  sensitive = true
}

Die Ping-URL steht in heartbeat_url und ist als sensibel markiert. Lesen Sie sie mit terraform output -raw backup_ping_url aus und tragen Sie sie in den Job ein.

Projekte, Alarmkanäle und Statusseiten

  • uptimecheck_project: ein Projekt, etwa ein Kunde, mit name und color. Wird es gelöscht, sind seine Monitore und Statusseiten keinem Projekt mehr zugeordnet; seine Kundenberichte und Kundenzugänge werden mitgelöscht.
  • uptimecheck_alert_channel: E-Mail, Slack per Incoming Webhook, Microsoft Teams, Discord, Google Chat, Mattermost, PagerDuty, ntfy, Pushover und Webhooks. Adresse oder Schlüssel stehen in config, das die API nie zurückgibt; eine Änderung in der App gilt daher nicht als Drift. Mit delay_minutes (5, 10, 15, 30 oder 60) wird der Kanal zur Eskalationsstufe. Das Signatur-Secret eines Webhooks steht in webhook_secret und wird nur beim Anlegen des Kanals zurückgegeben.
  • uptimecheck_status_page: eine Statusseite mit Titel, Gestaltung und components, den Monitoren, die Besucher sehen, in Reihenfolge und optional gruppiert. Passwort, E-Mail-Zugriffsliste und eigenes CSS legen Sie in der App fest, Terraform lässt sie unberührt. Beim Löschen werden ihre Abonnenten, geschriebenen Updates und Besucherstatistiken mitgelöscht.
  • Die Datenquellen uptimecheck_alert_channels, uptimecheck_projects und uptimecheck_status_pages listen auf, was vorhanden ist. Nutzen Sie die erste für SMS-, Telegram-, Push- und Add-to-Slack-Kanäle, die in der App eingerichtet werden.

Bestehendes übernehmen

In der App angelegte Monitore, Projekte, Alarmkanäle und Statusseiten lassen sich über ihre ID importieren:

terraform import uptimecheck_monitor.checkout mon_...
terraform import uptimecheck_project.acme prj_...
terraform import uptimecheck_alert_channel.slack ch_...
terraform import uptimecheck_status_page.public sp_...

Bei einem importierten Alarmkanal werden Adresse und Signatur-Secret eines Webhooks nicht zurückgelesen. Jede Ressource und jedes Attribut ist in der Terraform Registry dokumentiert. Mehr zur Terraform-Integration, zu API-Schlüsseln und zur REST API.

War dieser Artikel hilfreich?

Testen Sie es in Ihrem eigenen Workspace

14 Tage kostenlos testen · Danach gratis für 20 Monitore · Keine Kreditkarte

Kommen Sie nicht weiter?

Schreiben Sie an support@uptimecheck.com, wir antworten innerhalb von 24 Stunden.

Sie möchten automatisieren? Die API-Referenz deckt REST-API, Webhooks, Cron-Job-Pings und MCP ab.